PROCX e PROCV são funções de busca do Excel, você informa um valor (um código, um nome, um número de pedido) e elas devolvem a informação correspondente em outra coluna.
A função PROCV é usada há décadas. A função PROCX foi anunciada pela Microsoft justamente para substituí-la, junto com a PROCH.
Neste artigo, você vai ver as duas funções lado a lado, entender a diferença entre elas, conhecer as armadilhas que geram resultados errados sem aviso e saber qual escolher em cada situação.
O que é a função PROCV e como ela funciona
O PROCV procura um valor na primeira coluna de uma tabela e devolve o conteúdo de outra coluna da mesma linha, indicada por um número.
=PROCV(valor_procurado; matriz_tabela; núm_índice_coluna; [procurar_intervalo])- valor_procurado: o que você quer encontrar (ex.: o número do pedido).
- matriz_tabela: a tabela inteira onde a busca acontece.
- núm_índice_coluna: o número da coluna que tem a resposta, contando da esquerda para a direita.
- procurar_intervalo: FALSO para correspondência exata, VERDADEIRO (ou vazio) para correspondência aproximada.
Esse último argumento é a origem de muitos erros. Se você esquecer de preenchê-lo, o PROCV assume correspondência aproximada e pode devolver um valor errado sem mostrar nenhum aviso.
O que é a função PROCX e o que ela muda
O PROCX pesquisa um intervalo e retorna o item correspondente à primeira ocorrência encontrada.
A grande mudança é que ela separa onde procurar de o que devolver.
=PROCX(pesquisa_valor; pesquisa_matriz; matriz_retorno; [se_não_encontrada]; [modo_correspondência]; [modo_pesquisa])- pesquisa_valor: o que procurar.
- pesquisa_matriz: a coluna (ou linha) onde procurar.
- matriz_retorno: a coluna (ou linha) com a resposta.
- se_não_encontrada: o que exibir se nada for encontrado (opcional).
- modo_correspondência e modo_pesquisa: como a busca deve ser feita (opcionais, explicados mais adiante).
Para a busca exata mais comum, bastam três argumentos. Não há número de coluna para contar, e a correspondência exata já é o padrão.
Como exemplo vamos usar a planilha abaixo, clique no botão para baixar.
PROCX vs PROCV lado a lado
Antes dos exemplos, um resumo das diferenças principais:
| Critério | PROCV | PROCX |
| Argumentos para busca exata | 4 | 3 |
| Correspondência padrão | Aproximada (se omitida) | Exata |
| Busca à esquerda | Não | Sim |
| Indicação da coluna de retorno | Número da coluna | Intervalo da coluna |
| Inserir/remover colunas | Pode quebrar o resultado | Ajusta automaticamente |
| Tratamento de “não encontrado” | Precisa de SEERRO | Argumento próprio |
| Buscar do último para o primeiro | Não | Sim |
| Retornar várias colunas de uma vez | Não (uma fórmula por coluna) | Sim |
| Busca vertical e horizontal | Só vertical (horizontal é a PROCH) | Ambas |
| Compatibilidade | Todas as versões do Excel | Microsoft 365, Excel 2021, 2024 e Excel para Web |
Aplicação prática
1. Busca exata simples
Objetivo: descobrir o cliente do pedido 1008.
=PROCV(1008; A2:G17; 3; FALSO)- O PROCV procura 1008 na primeira coluna da tabela (A).
- O 3 indica a terceira coluna da tabela (Cliente).
- O FALSO obriga a correspondência exata.
=PROCX(1008; A2:A17; C2:C17)- Procura 1008 na coluna A.
- Devolve o valor da mesma linha na coluna C.
- A correspondência exata já é o padrão.
Resultado nas duas: Restaurante Sabor Sul.
2. Buscar à esquerda
Objetivo: descobrir o número do primeiro pedido do cliente “Hotel Beira-Mar”.
O cliente está na coluna C e o número do pedido está na coluna A, à esquerda.
A PROCV não consegue fazer essa busca, porque ela só procura na primeira coluna do intervalo e só devolve colunas à direita.
A alternativa clássica é combinar ÍNDICE e CORRESP:
=ÍNDICE(A2:A17; CORRESP("Hotel Beira-Mar"; C2:C17; 0))
Com a PROCX, a lógica continua a mesma de sempre:
=PROCX("Hotel Beira-Mar"; C2:C17; A2:A17)
Resultado: 1005.
3. Tratar valores não encontrados
Objetivo: buscar o pedido 1020, que não existe, e exibir uma mensagem amigável.
=SEERRO(PROCV(1020; A2:G17; 3; FALSO); "Pedido não encontrado")
=PROCX(1020; A2:A17; C2:C17; "Pedido não encontrado")
Resultado nas duas: Pedido não encontrado.
Existe uma diferença sutil aqui.
O SEERRO esconde qualquer erro, inclusive erros de fórmula mal montada.
O quarto argumento da PROCX age apenas quando o valor não é encontrado, então outros problemas (como #VALOR!) continuam aparecendo.
4. Retornar várias colunas com uma única fórmula
Objetivo: trazer cliente, código e produto do pedido 1010.
Com a PROCV, seriam três fórmulas, cada uma com um número de coluna diferente (3, 4 e 5).
Com a PROCX, basta indicar um intervalo de retorno com várias colunas:
=PROCX(1010; A2:A17; C2:E17)Resultado (em três células, lado a lado): Mercado Bom Preço | P-725 | Arroz Tipo 1 5kg.
O resultado se espalha automaticamente para as células vizinhas. Deixe essas células vazias, ou o Excel vai exibir o erro #DESPEJAR!.
5. Inserir uma coluna no meio da tabela
Imagine que alguém insere uma coluna “Vendedor” entre Pedido e Data. O cliente passa da coluna C para a coluna D.
- O PROCV com núm_índice_coluna = 3 continua apontando para a terceira coluna, que agora é Data. A fórmula não dá erro: ela simplesmente passa a devolver a informação errada.
- O PROCX, que referencia C2:C17, é ajustada pelo Excel para D2:D17 e continua devolvendo o cliente.
Os argumentos opcionais da PROCX na prática
Os dois últimos argumentos são os que mais ampliam o uso da função.
Modo de correspondência (5º argumento):
| Valor | Comportamento |
| 0 | Correspondência exata (padrão) |
| -1 | Exata ou o próximo item menor |
| 1 | Exata ou o próximo item maior |
| 2 | Caracteres curinga (*, ? e ~) |
| 3 | Expressões regulares (regex), apenas no Microsoft 365 |
Modo de pesquisa (6º argumento):
| Valor | Comportamento |
| 1 | Do primeiro para o último (padrão) |
| -1 | Do último para o primeiro (busca reversa) |
| 2 | Busca binária em dados ordenados de forma crescente |
| -2 | Busca binária em dados ordenados de forma decrescente |
Faixa de valor (modo -1)
Considere a tabela auxiliar referente a comissões nas colunas J e K:
Objetivo: encontrar a comissão de cada pedido de acordo com o valor.
=PROCX(G2;$J$2:$J$5;$K$2:$K$5;;-1)- G2 é o valor do pedido (1.240,00).
- O -1 diz: se não houver valor exato, use a faixa imediatamente menor.
- O quarto argumento fica vazio (repare nos dois pontos e vírgulas seguidos).
Resultado: 3%, porquê R$ 1.240 está entre R$ 1.000 e R$ 2.000. No pedido 1010 (R$ 3.200,00), o resultado é 5%.
A versão com PROCV seria:
=PROCV(G2; $J$2:$K$5; 2; VERDADEIRO)O PROCV exige que a tabela de faixas esteja em ordem crescente, ou o resultado sai errado. A PROCX com modo -1 em pesquisa padrão não depende dessa ordenação.
Último registro de um cliente (modo de pesquisa -1)
Objetivo: descobrir o valor da última compra do Mercado Bom Preço.
=PROCX("Mercado Bom Preço"; C2:C17; G2:G17; "Sem compras"; 0; -1)- O 0 mantém a correspondência exata.
- O -1 no sexto argumento faz a busca começar de baixo para cima.
Resultado: 2.480,00 (pedido 1015). Trocando G2:G17 por B2:B17, você obtém a data da última compra: 23/03/2026.
Isso só funciona como “último” porque a base está em ordem cronológica.
Se os pedidos forem lançados fora de ordem, o resultado será o último na lista, não necessariamente o mais recente.
Busca parcial com curinga (modo 2)
Objetivo: encontrar o valor do primeiro pedido que contenha “Arroz” no nome do produto.
=PROCX("*Arroz*"; E2:E17; G2:G17; "Não encontrado"; 2)Resultado: 3.200,00 (pedido 1010).
O PROCV também aceita curingas quando está em correspondência exata.
No PROCX, o modo 2 precisa ser declarado; sem ele, o asterisco é tratado como texto comum.
Expressões regulares (modo 3)
Desde dezembro de 2024, a PROCX no Microsoft 365 aceita REGEX, útil quando os dados não são padronizados.
Por exemplo, para encontrar o primeiro pedido de “Refrigerante” ou “Suco”:
=PROCX("Refrigerante|Suco"; E2:E17; C2:C17; "Não encontrado"; 3)Resultado: Lanchonete Ponto Certo (pedido 1007).
A barra vertical | significa “ou”. Esse recurso não existe no Excel 2021 nem no 2024; em arquivos compartilhados com quem usa essas versões, a fórmula não vai funcionar.
Buscas com mais de uma condição
Por padrão, as duas funções aceitam apenas um critério.
No PROCX, há duas saídas práticas.
Opção 1: concatenar critérios
=PROCX("Restaurante Sabor Sul" & "Bebidas"; C2:C17 & F2:F17; G2:G17; "Não encontrado")O & junta cliente e categoria em um único texto, tanto no valor procurado quanto na coluna de pesquisa.
Opção 2: lógica booleana
=PROCX(1; (C2:C17="Restaurante Sabor Sul") * (F2:F17="Bebidas"); G2:G17; "Não encontrado")Cada comparação gera uma lista de VERDADEIRO/FALSO. A multiplicação transforma isso em 1 (as duas condições atendidas) ou 0. A PROCX procura o primeiro 1.
Resultado nas duas: 1.410,00 (pedido 1008).
Erros comuns e armadilhas
#NOME?
Aparece quando a planilha é aberta em uma versão que não reconhece a PROCX, como Excel 2016 e 2019.
A solução é usar uma versão compatível ou trocar por PROCV ou ÍNDICE e CORRESP no arquivo compartilhado.
#N/D quando o valor “está lá”
Esse erro aparece em ambas as funções, e a causa quase sempre está nos dados, não na fórmula:
- Número armazenado como texto: o pedido 1008 digitado como texto não corresponde ao número 1008.
- Espaços invisíveis: “Hotel Beira-Mar ” (com espaço no final) é diferente de “Hotel Beira-Mar”.
- Caracteres ocultos: comuns em dados copiados de sistemas e páginas da web.
Para limpar, funções como ARRUMAR (espaços extras), TIRAR (caracteres não imprimíveis) e VALOR (texto para número) ajudam.
Em bases recorrentes, o Power Query resolve isso de forma automática a cada atualização.
#VALOR!
No PROCX, a matriz de pesquisa e a matriz de retorno precisam ter o mesmo tamanho. Uma fórmula como esta gera erro:
=PROCX(1008; A2:A17; C2:C15)A pesquisa tem 16 linhas e o retorno tem 14. Ajuste os dois intervalos para começar e terminar nas mesmas linhas.
Busca binária em dados fora de ordem
Os modos de pesquisa 2 e -2 são rápidos, mas exigem dados ordenados. Se a ordenação estiver errada, a PROCX pode devolver um resultado incorreto sem nenhum erro aparente.
Use busca binária apenas quando:
- a base for grande o suficiente para a velocidade fazer diferença;
- a ordenação for garantida (por exemplo, uma etapa de classificação no Power Query antes de carregar os dados).
O quarto argumento escondendo problemas
Preencher o argumento se_não_encontrada com texto vazio (“”) deixa a planilha limpa, mas também esconde falhas reais de dados.
Um código digitado errado vira uma célula em branco que ninguém percebe.
A recomendação é montar a fórmula primeiro sem tratamento, confirmar que os resultados estão corretos e só então incluir uma mensagem explícita, como “Não encontrado”, que deixa claro que algo precisa ser verificado.
Quando usar PROCV e quando usar PROCX
Use a PROCX quando:
- todos que usam a planilha têm Microsoft 365, Excel 2021, 2024 ou Excel para Web;
- a planilha vai ser editada por várias pessoas e colunas podem ser inseridas;
- a busca precisa ser feita à esquerda;
- você precisa do último registro, de faixas de valores ou de várias colunas de retorno;
- você quer tratar valores não encontrados sem esconder outros erros.
Mantenha a PROCV quando:
- o arquivo será aberto em Excel 2019 ou anterior, por um cliente, fornecedor ou outro setor;
- a planilha já funciona bem e não há motivo para reescrever centenas de fórmulas;
- você precisa de compatibilidade máxima com outros programas de planilha.
Para quem está montando planilhas novas, a própria Microsoft recomenda a PROCX no lugar da PROCV e da PROCH.
Conclusão
O PROCV procura na primeira coluna e devolve uma coluna indicada por número.
O PROCX separa onde procurar e o que devolver, busca em qualquer direção, usa correspondência exata por padrão, trata valores não encontrados e não quebra quando a tabela muda.
Aplique agora o que aprendeu nesse tutorial com uma base que você usa com frequência para assimilar melhor os conceitos apresentados. Saber escolher a ferramenta certa para cada situação é o que transforma uma planilha que “funciona” em uma planilha em que a sua equipe confia.
Artigos Relacionados
Sobre o Autor
0 Comentários